Site DB (#27)

return ((caller == this) || caller_perms().wizard) ? pass(@args) | E_PERM;
.

":add(player,site)";
if (!caller_perms().wizard)
    return E_PERM;
endif
who = args[1];
domain = args[2];
if (this:domain_literal(domain))
    "... just enter it...";
    l = this:find_exact(domain);
    if (l == $failed_match)
        this:insert(domain, {who});
    elseif (!(who in l))
        this:insert(domain, setadd(l, who));
    endif
else
    "...an actual domain name; add player to list for that domain...";
    "...then add domain itself to list for the next larger domain; repeat...";
    "...  Example:  domain == foo.bar.edu:  ";
    "...            enter #who  on foo.bar.edu list";
    "...            enter `foo' on bar.edu list";
    "...            enter `bar' on edu list";
    if (!(dot = index(domain, ".")))
        dot = length(domain) + 1;
        domain = tostr(domain, ".", this.domain);
    endif
    prev = who;
    while ($failed_match == (l = this:find_exact(domain)))
        this:insert(domain, {prev});
        if (dot)
            prev = domain[1..dot - 1];
            domain = domain[dot + 1..length(domain)];
        else
            return;
        endif
        dot = index(domain, ".");
    endwhile
    if (!(prev in l))
        this:insert(domain, {@l, prev});
    endif
    return;
endif
.

":load([start]) -- reloads site_db with the connection places of all players.";
"This routine calls suspend() if it runs out of time.";
"WIZARDLY";
"...needs to be able to read .all_connect_places";
if (!$perm_utils:controls(caller_perms(), this))
    return E_PERM;
endif
plist = players();
if (!args)
    this:clearall();
elseif (i = args[1] in plist)
    plist[1..i - 1] = {};
else
    return E_INVARG;
endif
for p in (plist)
    if (valid(p) && (is_player(p) && (!$object_utils:isa(p, $guest))))
        "... player may be recycled or toaded during the suspend(),...";
        "... guests login from everywhere...";
        for c in (p.all_connect_places)
            this:add(p, c);
            if ($command_utils:running_out_of_time())
                player:tell("...", p);
                suspend(0);
            endif
        endfor
    endif
endfor
.

":domain_literal(string)";
" => true iff string is a domain literal (i.e., numeric IP address).";
if (10 <= (len = length(hnum = strsub(args[1], ".", ""))))
    return tonum(hnum[1..9]) && tonum(hnum[6..len]);
else
    return tonum(hnum);
endif
"SLEAZY CODE ALERT";
"... what I wanted to do was return tonum(strsub(args[1],\".\",\"\"))";
"... but on a 32-bit machine, this has a 1 in 4294967296 chance of failing";
"... (e.g., on \"42.94.967.296\", though I'll grant this particular example";
"...  entails some very strange subnetting on net 42, to say the least).";
"... So we do something that is guaranteed to work so long as internet";
"... addresses stay under 32 bits --- a while yet...";
"";
"... As soon as we're sure match() is working, this will become a one-liner:";
return match(args[1], "[0-9]+%.[0-9]+%.[0-9]+%.[0-9]+");
.

if (caller_perms().wizard)
    pass();
    this:clearall();
    this.domain = "localdomain";
endif
.